PIC单片机应用专题二：显示接口及编程

单片机的显示输出常用来显示系统参数、运行结果及人机对话窗口。常用的显示器主要有LED（数码管）和LCD（液晶）。因LED应用简单、价格低廉得到广泛应用，下面主要对其应用进行介绍。

数码管有共阴和共阳之分，常见的结构形式有单个和四位一体，一般由8字段构成，显示方式有静态显示和动态显示两种方式。

静态显示：

在静态显示方式下，共阴极或共阳极点连接在一起接地或接高电平。每位的段选项线与一个8位并行口相连。只要在该位的段选线上保持段选码电平，该位就能保持相应的显示字符。8位并行口可以是单片机的I/O口或者采用串行输入/并行输出的移位寄存器（常用为74HC164、74HC595）

下面是试验板LED动态显示的电路图：

如果要显示某字符，首先要把这个字符转换为相应的字形码，然后通过单片机的串行口，将编码数据发送到74HC595，74HC595再将接受到的数据以并行的方式加到数码管上，并通过RCK将输出数据锁存。

下面是其应用实例：

;**********************************************************

;* display.ASM

;**********************************************************

;* 利用SPI口实现4位数码管显示，在demo40板上通过调试

;* 调试时硬件设置：SW2的1,2断开

;**********************************************************

;* 显示数据存放在disp1~disp4(20~23),disp1为右边第一位

;**********************************************************

list p=16f877

; Include file, change directory if needed

include "p16f877.inc"

; Start at the reset vector

DISP1 EQU 20H

DISP2 EQU DISP1+1

DISP3 EQU DISP2+1

DISP4 EQU DISP3+1

count EQU DISP4+1

T1 EQU count+1

ORG 0x000

nop

goto start

;****************************************************************************

;以下为显示模块

CONVERT

ADDWF PCL,1 ;不带小数点的共阴极码表

RETLW 0X3F ;0

RETLW 0X06 ;1

RETLW 0X5B ;2

RETLW 0X4F ;3

RETLW 0X66 ;4

RETLW 0X6D ;5

RETLW 0X7D ;6

RETLW 0X07 ;7

RETLW 0X7F ;8

RETLW 0X6F ;9

RETLW 0X00 ;DARK

RETLW 0X71 ;F

RETLW 0X37 ;N

;******************************************************************************

init

banksel TRISC

movlw B'00010000' ;RC4作为SDI

movwf TRISC

movlw 0xc0

movwf SSPSTAT

banksel SSPCON

clrf PORTC

movlw B'00110010' ;

movwf SSPCON

return

disp movlw 05h

movwf count

movlw 20h

movwf FSR

bcf PORTC,6

dsnext decfsz count,1

goto dbtran

goto dsend

dbtran movf INDF,0

CALL CONVERT ;赋1位数据显示码

call out_in

incf FSR,1

goto dsnext

dsend bsf PORTC,6

return

out_in movwf SSPBUF

loop1

banksel SSPSTAT

btfss SSPSTAT,BF

goto loop1

bcf STATUS,RP0

movf SSPBUF,w

return

start call init

movlw 01h

movwf DISP1

movlw 02h

movwf DISP2

movlw 03h

movwf DISP3

movlw 04h

movwf DISP4

agdisp call disp

goto agdisp

end

静态显示电路在位数较多时，字符更新速度慢，硬件成本高，在实际设计中，动态显示应用较多。下面介绍的是数码管的动态显示

动态显示：

动态显示是通过分时轮流选通数码管的公共端，使得各个数码管轮流导通，即各数码管是由脉冲电流导电的（导通时间一般为1ms）。当所有数码管依次显示一遍后，软件控制循环，使每位显示器分时点亮。这种方法不但能提高数码管的发光效率，并且由于各个数码管的字段线是并联使用的，因而大大简化了硬件线路。

下面是试验板的数码管动态显示电路图：

从图中可以看出RB口用作字形输出，RA口用作位扫描输出。由于PIC的I/O口最大输出电流为25ma，因此在字形输出回路要串电阻（一般为保证亮度，电流在10～15ma），而在扫描输出口电流为字形线电流的8倍，远超容许范围，因此加三极管驱动。另外可用8路三态反向缓冲器74HC240用作字形驱动，用6路反向门电路7406驱动位选。

动态显示最重要的是解决好亮度和字符闪烁问题。由于数码管具有余辉特性及人眼具有视觉暂留效应，所以适当选取循环扫描频率时，看上去所有数码管是同时点亮的，察觉不出有闪烁现象。不过这种方式数码管不宜太多（不超过8个），否则每个数码管分配到的实际导通时间会太少，使得亮度不足。另外要求扫描频率不能小于100Hz，否则就会出现闪烁现象。

下面是试验板数码管动态显示的实例：

;**********************************************************

;* display.ASM

;**********************************************************

;* 利用PORTB口实现4位数码管动态显示，在demo18板上通过调试

;**********************************************************

;* 显示数据存放在disp1~disp4(20~23),disp1为右边第一位

;**********************************************************

list p=16f628

; Include file, change directory if needed

include "p16f628.inc"

; Start at the reset vector

DISP1 EQU 20H

DISP2 EQU DISP1+1

DISP3 EQU DISP2+1

DISP4 EQU DISP3+1 ;以上为四位显示数据存放位

count EQU DISP4+1 ;动态显示位

T1 EQU count+1 ;延时数据存放位

ctrl EQU T1+1 ;动态显示控制位

ORG 0x000

nop

goto start

;****************************************************************************

;以下为显示模块

CONVERT

ADDWF PCL,1 ;不带小数点的共阴极码表

RETLW 0X3F ;0

RETLW 0X06 ;1

RETLW 0X5B ;2

RETLW 0X4F ;3

RETLW 0X66 ;4

RETLW 0X6D ;5

RETLW 0X7D ;6

RETLW 0X07 ;7

RETLW 0X7F ;8

RETLW 0X6F ;9

RETLW 0X00 ;DARK

RETLW 0X71 ;F

RETLW 0X37 ;N

;******************************************************************************

init

banksel TRISB

movlw B'00000000' ;A、B口为输出，初始数据为0

movwf TRISB

movwf TRISA

banksel PORTA

movwf PORTB

movwf PORTA

movlw 20h

movwf FSR ;显示数据存放首地址

movlw 01h

movwf ctrl ;动态显示控制初值

return

disp movlw 05h

movwf count ;动态显示为4位

disp1 decfsz count,1 ;动态显示一次完否？

goto dbtran ;否，继续显示

goto dsend ;是，结束显示

dbtran movf ctrl,0

movwf PORTA ;控制位赋A口

movf INDF,0

call CONVERT ;取显示数据

movwf PORTB ;显示数据赋B口

bcf STATUS,0 ;清进位标志

rlf ctrl,1 ;动态控制位左移

incf FSR,1 ;显示数据地址加1

call delay ;延时

CLRF PORTB

goto disp1 ;到下一位显示

dsend movlw 20h ;动态显示一周期完，恢复初始数据

movwf FSR

movlw 01h

movwf ctrl

return

delay movlw 0xff

movwf T1

delay1 decfsz T1,1

goto delay1

return

start call init

movlw 01h

movwf DISP1

movlw 02h

movwf DISP2

movlw 03h

movwf DISP3

movlw 04h

movwf DISP4

agdisp call disp

goto agdisp

end

动态扫描显示虽然硬件简单，但因必须反复循环显示，降低了单片机的工作效率，在一些实时性要求高的场合应用受到限制。